由于工坊限制，数字不可大于9999999

互动测试 10-32

蹲下测试 32-10

以下为代码，可直接复制粘贴到工坊。

如需要加密，请开启禁用规则。

变量
{
	全局:
		0: BaseData

	玩家:
		0: BaseParam
}

子程序
{
	0: Base1032
	1: Base3210
}

规则("初始化")
{
	事件
	{
		持续 - 全局;
	}

	动作
	{
		全局.BaseData = 数组(自定义字符串("0"), 自定义字符串("1"), 自定义字符串("2"), 自定义字符串("3"), 自定义字符串("4"), 自定义字符串("5"), 自定义字符串("6"), 自定义字符串("7"), 自定义字符串(
			"8"), 自定义字符串("9"), 自定义字符串("A"), 自定义字符串("B"), 自定义字符串("C"), 自定义字符串("D"), 自定义字符串("E"), 自定义字符串("F"), 自定义字符串("G"), 自定义字符串("H"),
			自定义字符串("I"), 自定义字符串("J"), 自定义字符串("K"), 自定义字符串("L"), 自定义字符串("M"), 自定义字符串("N"), 自定义字符串("O"), 自定义字符串("P"), 自定义字符串("Q"), 自定义字符串(
			"R"), 自定义字符串("S"), 自定义字符串("T"), 自定义字符串("U"), 自定义字符串("V"), 自定义字符串("W"), 自定义字符串("X"), 自定义字符串("Y"), 自定义字符串("Z"));
		禁用 全局.BaseData = 随机数组(全局.BaseData);
	}
}

规则("【子程序】进制1032")
{
	事件
	{
		子程序;
		Base1032;
	}

	动作
	{
		事件玩家.BaseParam = 数组(事件玩家.BaseParam, 自定义字符串(""));
		While(事件玩家.BaseParam[0] > 0);
			事件玩家.BaseParam[1] = 自定义字符串("{0}{1}", 全局.BaseData[事件玩家.BaseParam[0] % 32], 事件玩家.BaseParam[1]);
			事件玩家.BaseParam[0] = 取整(事件玩家.BaseParam[0] / 32, 下);
		End;
		事件玩家.BaseParam = 事件玩家.BaseParam[1];
	}
}

规则("【子程序】进制3210")
{
	事件
	{
		子程序;
		Base3210;
	}

	动作
	{
		事件玩家.BaseParam = 数组(事件玩家.BaseParam, 0);
		For 玩家变量(事件玩家, I, 0, 字符串长度(事件玩家.BaseParam[0]), 1);
			事件玩家.BaseParam[2 + 事件玩家.I] = 32 ^ (字符串长度(事件玩家.BaseParam[0]) - (事件玩家.I + 1)) * 数组值的索引(全局.BaseData, 截取字符串(事件玩家.BaseParam[0], 事件玩家.I,
				1));
		End;
		For 玩家变量(事件玩家, I, 2, 数量(事件玩家.BaseParam), 1);
			事件玩家.BaseParam[1] = 事件玩家.BaseParam[1] + 事件玩家.BaseParam[事件玩家.I];
		End;
		事件玩家.BaseParam = 事件玩家.BaseParam[1];
	}
}

规则("【TEST】互动 10转32进制")
{
	事件
	{
		持续 - 每名玩家;
		双方;
		全部;
	}

	条件
	{
		按钮被按下(事件玩家, 按钮(互动)) == 真;
	}

	动作
	{
		事件玩家.BaseParam = 随机整数(0, 9999999.000);
		小字体信息(事件玩家, 事件玩家.BaseParam);
		等待(0.250, 无视条件);
		调用子程序(Base1032);
		等待(0.250, 无视条件);
		小字体信息(事件玩家, 事件玩家.BaseParam);
	}
}

规则("【TEST】蹲下 32转10进制")
{
	事件
	{
		持续 - 每名玩家;
		双方;
		全部;
	}

	条件
	{
		按钮被按下(事件玩家, 按钮(蹲下)) == 真;
	}

	动作
	{
		事件玩家.BaseParam = 自定义字符串("{0}{1}{2}", 随机整数(0, 8), 自定义字符串("{0}{1}", 数组随机取值(全局.BaseData), 数组随机取值(全局.BaseData)), 自定义字符串("{0}{1}",
			数组随机取值(全局.BaseData), 数组随机取值(全局.BaseData)));
		小字体信息(事件玩家, 事件玩家.BaseParam);
		等待(0.250, 无视条件);
		调用子程序(Base3210);
		等待(0.250, 无视条件);
		小字体信息(事件玩家, 事件玩家.BaseParam);
	}
}